/*
 * Copyright 2013-2026, Seqera Labs
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

plugins {
    id 'io.nextflow.nextflow-plugin' version "${nextflowPluginVersion}"
    id 'java-test-fixtures'
}

nextflowPlugin {
    nextflowVersion = '26.04.0'

    provider = "${nextflowPluginProvider}"
    description = 'Integrates with Seqera Platform for comprehensive workflow monitoring, resource tracking, and cache management capabilities'
    className = 'io.seqera.tower.plugin.TowerPlugin'
    useDefaultDependencies = false
    generateSpec = false
    extensionPoints = [
        'io.seqera.tower.plugin.TowerConfig',
        'io.seqera.tower.plugin.TowerFactory',
        'io.seqera.tower.plugin.TowerFusionToken',
        'io.seqera.tower.plugin.auth.AuthCommandImpl',
        'io.seqera.tower.plugin.launch.LaunchCommandImpl',
        'io.seqera.tower.plugin.fs.SeqeraPathFactory'
    ]
}

sourceSets {
    main.java.srcDirs = []
    main.groovy.srcDirs = ['src/main']
    main.resources.srcDirs = ['src/resources']
    test.groovy.srcDirs = ['src/test']
    test.java.srcDirs = []
    test.resources.srcDirs = []
}

configurations {
    // see https://docs.gradle.org/4.1/userguide/dependency_management.html#sub:exclude_transitive_dependencies
    runtimeClasspath.exclude group: 'org.slf4j', module: 'slf4j-api'
}

dependencies {
    compileOnly project(':nextflow')
    compileOnly 'org.slf4j:slf4j-api:2.0.17'
    compileOnly 'org.pf4j:pf4j:3.14.1'
    compileOnly 'io.seqera:lib-httpx:2.1.0'
    api 'io.seqera:lib-platform-oidc:0.1.0'

    api('io.seqera:tower-api:1.121.0') {
        exclude group: 'io.micronaut.servlet'
    }
    api "com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.21.1"
    api "com.fasterxml.jackson.core:jackson-databind:2.21.1"

    testImplementation(testFixtures(project(":nextflow")))
    testImplementation "org.apache.groovy:groovy:4.0.31"
    testImplementation "org.apache.groovy:groovy-nio:4.0.31"
    testImplementation "org.apache.groovy:groovy-json:4.0.31"
    // wiremock required by TowerFusionEnvTest
    testImplementation "org.wiremock:wiremock:3.13.1"
    // Address security vulnerabilities CVE-2022-45688 and CVE-2023-5072
    testImplementation 'org.json:json:20240303'
}